如何用ASP+Jmail 4.4进行邮件发送


关于Jmail我参考了很多代码,也有蓝色理想的,现在Jmail的最新版本是4.5,我的服务器是Jmail 4.4的,但是由于版本的不一样,网上流行的代码大都是基于Jmail 4.3的或是以前的版本,所以在我的Jmail 4.4的服务器上测试不成功。以下代码是在我的Jmail 4.4服务器上测试成功的,没有在其它版本的Jmail服务器上测试。有兴趣的朋友可以试一下。
<%
Set jmail = Server.CreateObject("JMAIL.Message") '建立发送邮件的对象
jmail.silent = true '屏蔽例外错误,返回FALSE跟TRUE两值j
jmail.logging = true '启用邮件日志
jmail.Charset = "GB2312" '邮件的文字编码为国标
jmail.ContentType = "text/html" '邮件的格式为HTML格式
jmail.AddRecipient "friend@blueidc.cn" '邮件收件人的地址
jmail.From = "user@blueidc.cn" '发件人的E-MAIL地址
jmail.MailServerUserName = "user" '登录邮件服务器所需的用户名
jmail.MailServerPassword = "password" '登录邮件服务器所需的密码
jmail.Subject = "Aspid Jmail Test" '邮件的标题
jmail.Body = "Aspid Jmail sender ok !" '邮件的内容
jmail.Priority = 1 '邮件的紧急程序,1 为最快,5 为最慢, 3 为默认值
jmail.Send("smtp.blueidc.cn") '执行邮件发送(通过邮件服务器地址)
jmail.Close() '关闭对象
response.write "Send email ok!"
%>


下面的是详细的ASP代码,适合ASP调用。

  '参数说明
  'Subject     : 邮件标题
  'MailAddress : 发件服务器的地址,如smtp.163.com
  'Email       : 收件人邮件地址
  'Sender      : 发件人姓名
  'Content     : 邮件内容
  'Fromer      : 发件人的邮件地址

  Sub SendAction(subject,mailaddress,email,sender,content,fromer)

Dim JMail,contentId
Set JMail = Server.CreateObject("JMail.Message")
JMail.Charset = "gb2312" ' 邮件字符集,默认为"US-ASCII"
' JMail.ISOEncodeHeaders = False ' 是否进行ISO编码,默认为True

' 发送者信息(可用变量方式赋值)
JMail.From = fromer ' 发送者地址
JMail.FromName = sender ' 发送者姓名
JMail.Subject = subject ' 邮件主题

' 身份验证
JMail.MailServerUserName = "mail@blueidc.cn" '身份验证的用户名
JMail.MailServerPassword = "******" ' 身份验证的密码

' 设置优先级,范围从1到5,越大的优先级越高,3为普通
JMail.Priority = 3

JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")

' 加入一个收件人【变量email:收件人地址】可以同一语句重复加入多个
FriendEmail=email '接收人邮件地址
JMail.AddRecipient(FriendEmail)

' 加入附件【变量filename:附件文件的绝对地址,确保用户IUSR_机器名有访问的权限】
' 【参数设置是(True)否(False)为Inline方式】
'contentId = JMail.AddAttachment (Server.MapPath("jmail.asp"), True)

' 邮件主体(HTML(注意信件内链接附件的方式))
MailBody = MailBody & "<html><head><META content=zh-cn http-equiv=Content-Language><meta http-equiv=""Content-Type"" content=""text/html; charset=gb2312""><style type=text/css>BODY {FONT-SIZE: 9pt}</style></head><body>"
MailBody = MailBody & content
MailBody = MailBody & "</body></html>"
JMail.HTMLBody = MailBody

' 邮件主体(文本部分)
JMail.Body = content

' 发送【调用格式:objJMail.Send([username:password@]SMTPServerAddress[:Port])】
' 发送邮件的服务器
JMail.Send(mailaddress)

' 关闭并清除对象
JMail.Close()
Set JMail = Nothing
  End Sub
  
  '调用此Sub的例子
  Dim strSubject,strEmail,strMailAdress,strSender,strContent,strFromer
  strSubject         = "这是一封用JMAIL发送的测试邮件"
  strContent        = "JMail组件发送测试成功!"
  strEmail            = "user@163.com"
  strFromer          = "mail@blueidc.cn"
  strMailAddress  = "smtp.mail.sogou.com"
  strSender         = "邮件发送者"

  Call SendAction (strSubject,strMailaddress,strEmail,strSender,strContent,strFromer)

[本日志由 随然 于 2007-03-16 11:15 AM 编辑]
上一篇: 女大学生的文雅性暗示
下一篇: 存钱!
文章来自: 本站原创
引用通告: 查看所有引用 | 我要引用此文章
Tags: ASP 程序 邮件
相关日志:
评论: 1 | 引用: 193 | 查看次数: 16200
发表评论
昵 称:
密 码: 游客发言不需要密码.
邮 箱: 邮件地址支持Gravatar头像,邮箱地址不会公开.
网 址: 输入网址便于回访.
内 容:
验证码:
选 项:
虽然发表评论不用注册,但是为了保护您的发言权,建议您注册帐号.
字数限制 10 字 | UBB代码 关闭 | [img]标签 关闭